小编给大家分享一下怎么用批处理实现一行内容分行输出，相信大部分人都还不怎么了解，因此分享这篇文章给大家参考一下，希望大家阅读完这篇文章后大有收获，下面让我们一起去了解一下吧！
a.txt：
代码:
aA1一bB2二cC3三dD4四eE5五fF6六gG7七hH8八iI9九
输出如下：
代码:
abcdefghi
ABCDEFGHI
123456789
一二三四五六七八九
唯一要求，老手略过，留给新手做练习，不能直接echo。
请先发现其中的规律。
其他，生成临时文件、代码超过一页都不重要，正确输出即可。
523066680：
代码如下:
@echo off
setlocal enabledelayedexpansion
set a=-1
for /f "tokens=*" %%a in ('type 1.x') do set hang=%%a
:a
set /a a+=1
set /a b=%a%
:b
set hang%a%=!hang%a%!!hang:~%b%,1!
set /a b=%b%+4
if not "!hang:~%b%,1!"=="" goto :b
echo,!hang%a%!
if %a% leq 2 goto :a
pause
这个思路很直接，没啥特别之处，就是设
第一行为1,5,9,13,……位上的
第二行为2,6,10,14……位上的
随风：
代码如下:
@echo off&setlocal EnableDelayedExpansion
set "str=aA1一bB2二cC3三dD4四eE5五fF6六gG7七hH8八iI9九"
for /l %%a in (0 1 35) do (
set /a n+=1
call set .!n!=%%.!n!%%!str:~%%a,1!
set /a n=n%%4
)
for /f "tokens=2 delims==" %%a in ('set .') do echo %%a
pause>nul
terse：
代码如下:
@echo off&setlocal EnableDelayedExpansion
set "str=aA1一bB2二cC3三dD4四eE5五fF6六gG7七hH8八iI9九"
for /l %%i in (0 1 3) do for /l %%j in (%%i 4 35) do set %%i=!%%i!!str:~%%j,1!
for /l %%i in (0 1 3) do echo !%%i!
pause>nul
netbenton：
代码如下:
@echo off&setlocal ENABLEDELAYEDEXPANSION
set "x=aA1一bB2二cC3三dD4四eE5五fF6六gG7七hH8八iI9九"
for /l %%a in (0,1,3) do ((for /l %%b in (%%a,4,35) do set/p=!x:~%%b,1!<nul)&echo.)
pause
以上是“怎么用批处理实现一行内容分行输出”这篇文章的所有内容，感谢各位的阅读！相信大家都有了一定的了解，希望分享的内容对大家有所帮助，如果还想学习更多知识，欢迎关注编程网行业资讯频道！
